Konvertering fra en type til en annen

Hva

Det er flere muligheter for å ta innholdet i en variabel over i en variabel av en annen type, vi kan konvertere data. Det er lurt å sette seg litt inn i dette for ikke å få uventede overraskelser siden.

En full beskrivelse av alle mulighetene finner du under overskriften "Conversion" i dokumentasjonen til Processing Reference.

Relevante Skisser

basis12, basis13, basis14

Nedenfor finner du tre skisser som tar for seg de vanligste situasjonene. Kopier dem og bruk dem som utgangspunkt for egne eksperimenter:

Tall til tekst

String S;
int i1,i2;
void setup(){
 size(100,100); 
 i1=13;
 i2=12;
}
void draw(){
  // skriver bare til console
  // vi kan legge tall til en tekst.
  S="Tall:"+i1+i2; 
  println(S);
  // det som er inne i parentesen gjøres først:
  S="Tall:"+(i1+i2); 
  println(S); 
  
  noLoop();
}

Heltall og desimaltall

// ser litt på int og float
int i1,i2,i3;
float f1;
void setup(){
 size(100,100);
 i1=15;
 i2=4;
}
void draw(){
  // skriver bare til console
  // vi vil ha resultatet av en divisjon
  i3=i1/i2;
  println("Resultat1: "+i3);
  
  f1=i1/i2;
  println("Resultat2: "+f1);
  
  f1=float(i1/i2);
  println("Resultat3: "+f1);
  
  f1=float(i1)/float(i2);
  println("Resultat4: "+f1);
  
  noLoop();
}

Tekst til tall

String S;
int i1,i2;
float f1;
void setup(){
 size(100,100);
 i1=15;
 i2=4;
}
void draw(){
  // skriver bare til console
  // vi vil finne et tall fra en text
  S="196";
  
  i1=int(S);
  println("Resultat1: "+i1); 
  
  S="196 og mere text";  
  i1=int(S);
  println("Resultat2: "+i1);
  
  S="196.78";
  i1=int(S);
  println("Resultat3: "+i1);
  
  S="196.78";
  f1=float(S);
  println("Resultat4: "+f1);
  
  noLoop();
}