Illustrasjon av lyd

Hva

Her skal vi bruke Minim-biblioteket til å vise amplituden til en sang. Minim, og hvordan du kopler det til er beskrevet på siden Lyd . Hvis du vil eksperimentere mer med dette så kopier de to pde-filene nedenfor inn i en katalog du kaller lydIllustrasjon. Inne i kataloger plasserer du også en data-katalog der du legger den sangen du vil se/høre.

Relevante Skisser

lydillustrasjon

Vi vil vise amplituden på to forskjellige måter. Det blir slik, litt forminsket:

Hovedskissen:

/*
lydillustrasjon
*/
import ddf.minim.*;
Minim minim;
AudioPlayer player;
pinneMann[] korps;
boolean showKorps=false;
void setup(){
  size(600,300);  
  // sett opp korpset
  korps=new pinneMann[6];
  for(int ix=0;ix<korps.length;ix++){
    korps[ix]=new pinneMann(50+ix*100,100);
  }
  // player
  minim = new Minim(this);
  // bytt filnavnet til din fil
  player = minim.loadFile("BruceSpringsteenHungryHeart.mp3");
  player.play();  
  frameRate(10);
}
void draw(){
  background(255);
  if(showKorps)
    drawKorpset();
  else
   drawKurver();
}
void drawKorpset(){
  for(int i=0;i < korps.length;i++){
    korps[i].tegn(player.left.get(0),
                  player.right.get(0));
  }
}
void mousePressed(){
  showKorps=!showKorps;
}

Kurvene:

void drawKurver(){
  translate(0,100);
  strokeWeight(1);
  stroke(255,0,0);
  for(int i = 0; i < player.bufferSize()/2; i++)
  {
    float x1 = map( i,   0, player.bufferSize()/2, 0, width );
    float x2 = map( i+1, 0, player.bufferSize()/2, 0, width );
    line(x1,player.left.get(i)*   70,
         x2,player.left.get(i+1)*   70);
  }
  translate(0,100);
  stroke(0,0,255);
  for(int i = 0; i < player.bufferSize()/2; i++)
  {
    float x1 = map( i,   0, player.bufferSize()/2, 0, width );
    float x2 = map( i+1, 0, player.bufferSize()/2, 0, width );
    line(x1,player.right.get(i)*   70,
         x2,player.right.get(i+1)*  70);
  }
 }

Jeg har også lagt inn en option slik at du kan se en alternativ form, en PinneMann. Denne er i betse fall uferdig. Du kan jo se om du kan forbedre den. Pinemannen er laget slik:

class pinneMann{
  int xpos;
  int ypos;
  
  public pinneMann(int x, int y){
    xpos=x;
    ypos=y;
  }
  
  // dette kan forbedres betraktelig
  public void tegn(float v1,float v2){
    float arm1=HALF_PI/v1;
    float arm2=-HALF_PI/v2;
    float ben1=PI/4;
    float ben2=-PI/4;
    stroke(0);
    strokeWeight(4);
    // systematisk bruk av pushMatrix og popMatrix
    pushMatrix();
      translate(xpos,ypos);
      scale(0.5,0.5);
      //hodr
      ellipse(0,0,30,30);
      // kropp
      line(0,15,0,100); 
      // skulder
      pushMatrix();
         translate(0,30);
          // arm1
          pushMatrix();
            rotate(arm1);
            stroke(255,0,0);
            line(0,0,0,50);
            stroke(0);
          popMatrix();
         //arm2
          pushMatrix();
            rotate(arm2);
            stroke(0,0,255);
            line(0,0,0,50);
            stroke(0);
          popMatrix();
      popMatrix();
   
      // hoft
      translate(0,100);
      //ben1
      pushMatrix();
        rotate(ben1);
        line(0,0,0,50);
      popMatrix();
      //ben2
      rotate(ben2);
      line(0,0,0,50);      
    popMatrix();
  }
  
}